Searching data from month and year

We have a data base with mulitple columns and a dashboard that reports on data with in a month year etc. Ive got the formula returning data my month but with within a specified year. so it reports on anyhing in said month in all the years.

Database looks like this

Im using this formula for the months but just cant work out and to add YEAR to this.

=SUMIF([Quote Date]:[Quote Date], MONTH(@cell ) = 4, [Project Value]:[Project Value])

How can i search the same but just in 2023 2022 etc.

thanks!!

Find more posts tagged with

Accepted answers

All comments

Matt Lynn ACT

@richard_abra You need multiple criteria so you'll need to use a sum(collect() instead. Try the below and modify as needed. I also added iferror() around the dates to prevent those common errors.

=sum(collect([Project Value]:[Project Value],[Quote Date]:[Quote Date], iferror(MONTH(@cell ),0) = 4,[Quote Date]:[Quote Date], iferror(year(@cell ),0) >=2022,[Quote Date]:[Quote Date],year(@cell )<=2023))

Paul Newcome

You can use an AND statement to double up on criteria without having to switch functions to repeat ranges.

=SUMIF([Quote Date]:[Quote Date], AND(IFERROR(MONTH(@cell), 0) = 4, IFERROR(YEAR(@cell), 0) = 2024), [Project Value]:[Project Value])

richard_abra

Works Perfect thanks both!!

Next one is how do i add the ability to search by customer wihin year month etc….?

So how many quotes have "Dolphin Solutons LTD" this month or YTD

Paul Newcome

You would need to switch over to a SUMIFS. It does have a slight variation on the syntax (range to sum comes first in this one), so make sure you follow that.

=SUMIFS({Range To Sum}, {1st Criteria Range}, 1st criteria, {2nd Criteria Range}, 2nd criteria, ……………….)

richard_abra

what am i doing wrong?

=SUMIFS([Project Value]:[Project Value], [Customer]:[Customer], "dolphin solutions ltd", IFERROR(MONTH(@cell), 0) = 4, [quote date]:[quote date], IFERROR(year(@cell), 0) > = 2024,[Quote Date]:[Quote Date], year(@cell) < = 2024))

heyjay

https://community.smartsheet.com/discussion/comment/447395#Comment_447395

Can you try this,

=SUMIFS(
[Project Value]:[Project Value], 
Customer:Customer, "dolphin solutions ltd", 
[Quote Date]:[Quote Date], IFERROR(MONTH(@cell ), 0) = 4, 
[Quote Date]:[Quote Date], 
  AND(
    IFERROR(YEAR(@cell ), 0) >= 2024, 
    IFERROR(YEAR(@cell ), 0) <= 2024))

However, this part does not make sense. What do you mean by this?

  AND(    
    IFERROR(YEAR(@cell ), 0) >= 2024,     
    IFERROR(YEAR(@cell ), 0) <= 2024))

Paul Newcome

Try this:

=SUMIFS([Project Value]:[Project Value], [Customer]:[Customer], "dolphin solutions ltd", [Quote Date]:[Quote Date], AND(IFERROR(MONTH(@cell), 0) = 4, IFERROR(year(@cell), 0) = 2024))

Sign in to join the conversation!

Quick Links

Component react.discussion.discussions had an error.

ref must be one of: categoryID, siteSectionID, category, category/categoryID, category/name, category/description, category/url, category/allowedDiscussionTypes, locale, siteSection, siteSection/basePath, siteSection/contentLocale, siteSection/sectionGroup, siteSection/sectionID, siteSection/name, siteSection/description, siteSection/apps, siteSection/attributes, layoutViewType, discussionID, commentID, page, latest, sort, sortType, lookupSort, discussion, discussion/name, tags, breadcrumbs, discussionApiParams, serverDraftID, serverDraft.