Como gerenciar e classificar registros de data e hora no Smartsheet

Marcela

Esta postagem de solução foi criada com base em um guia de práticas recomendadas originalmente desenvolvido por @Kelly Moore . Você pode encontrar a postagem original aqui: Converting a Text Timestamp into a Numeric Timestamp Value.

Problema:

quando os registros de data e hora são importados para o Smartsheet, eles geralmente precisam ser importados como campos de texto para manter o formato. Isso pode complicar a classificação e a organização cronológica dos dados, especialmente se os registros de data e hora forem usados para classificar ou identificar pontos de dados recentes.

Solução:

para manter a ordem cronológica e gerenciar efetivamente os registro de data e hora no Smartsheet, você pode converter os dados de data e hora em um valor numérico. Esse valor numérico facilitará a classificação, a organização e a análise posterior.

Instruções passo a passo:

1. Como importar o registro de data e hora como texto: garanta que os dados do seu registro de data e hora sejam importados como texto para o Smartsheet para manter o formato original. Neste exemplo, assumiremos que o formato éMM/DD/AAAA Thh:mm[1] (com a hora no formato militar).
2. Crie uma coluna para a conversão da data:adicione uma coluna chamada Data do carimbo de data e hora à planilha e use a seguinte fórmula para converter o formato de texto em uma data:

=DATE(VALUE(MID([Data de entrada em formato de texto]@row; 7; 4)); VALUE(LEFT([Data de entrada em formato de texto]@row; 2)); VALUE(MID([Data de entrada em formato de texto]@row; 4; 2)))

3. Crie uma coluna para conversão da hora:

Em seguida, crie uma coluna chamada Hora do carimbo de data e hora e aplique a fórmula a seguir para extrair a hora:

=TIME(MID([Data de entrada em formato de texto]@row; 13; 5))

4. Gere um registro de data e hora no formato Juliano:

Adicione uma coluna chamada Carimbo de data e hora juliano para converter a data e a hora em um valor numérico:

=VALUE(RIGHT([Data do carimbo de data e hora]@row; 2) + YEARDAY([Data do carimbo de data e hora]@row) + "." + LEFT([Hora do carimbo de data e hora]@row; 2) + RIGHT([Hora do carimbo de data e hora]@row; 2))

Explicação:

• A função RIGHT([Data do carimbo de data e hora]@row; 2) extrairá os dois últimos dígitos do ano.
• A função YEARDAY([Data do carimbo de data e hora]@row) fornecerá o dia do ano.
• Em seguida, a hora será convertida em um valor decimal de quatro dígitos.
• Toda a fórmula será envolvida no VALUE para garantir que o resultado seja numérico.

5. Classificação dos registos de data e hora: se o seu caso exigir a identificação dos pontos de dados mais recentes, crie uma coluna chamada Ordem e use a seguinte fórmula para classificar os registros de data e hora no formato juliano:

=RANKAVG([Carimbo de data e hora juliano]@row; [Carimbo de data e hora juliano]:[ Carimbo de data e hora juliano]; 0)

• Essa fórmula classificará os registros de data e hora, permitindo que você identifique os registros mais recentes.

Observação:esta melhor prática é recomendada para usuários que precisem manter a integridade dos registros de data e hora no Smartsheet, garantindo a classificação cronológica e análise precisas.

Funções utilizadas: TIME, MID, DATE, VALUE, LEFT, RIGHT, MID, YEARDAY, RANKAVG.