SUMIF function not working

Jennifer Parins

=SUMIFS({GM Compliance Trained}, {GM Compliance Training Dept}, Department@row , {Compliance Training Date}, MONTH(7, 8, 9))

GM Compliance Trained is the number of employees trained.

I am trying to sum the number of employees trained in each department during 3rd quarter (July 1-Sep 30). Thinking I need an IFERROR in there but not sure where.

Any help would be very appreicated.

jmyzk_cloudsmart_jp

Hi @Jennifer Parins

If you want Q3 for a specific year:

=SUMIFS(

  {GM Compliance Trained},

  {GM Compliance Training Dept}, Department@row,

  {Compliance Training Date}, >= DATE(YEAR(TODAY()), 7, 1),

  {Compliance Training Date}, <= DATE(YEAR(TODAY()), 9, 30)

)

(Swap YEAR(TODAY()) for a fixed year if needed.)

If you want “any year, but months 7–9”:

=SUM(COLLECT(

  {GM Compliance Trained},

  {GM Compliance Training Dept}, Department@row,

  {Compliance Training Date}, MONTH(@cell) >= 7,

  {Compliance Training Date}, MONTH(@cell) <= 9

))

Why yours didn’t work: MONTH(7,8,9) isn’t valid—MONTH() takes a single date. For multi-month logic, use a range check (>=7 and <=9) or sum three separate months' SUM(COLLECT()).