I am looking for the formula to get automatically percentage calculated based on the status?

I do not want it based on duration or end/due date because if the date is in past it shows 100% even if the task is still in progress (crossed the end/due date). I am not sure is there any way or not. Just need little clarification and suggestion please.

Answers

  • Genevieve P.
    Genevieve P. Employee Admin

    Hi @Abhilasha

    What I would do in this instance is write an IF statement before your other formula so that if "Done" is in the Status column, the "% Complete" will automatically be 100, even if the End Date is in the future:

    =IF(Status@row = "Done", 1

    Then the next instruction could be that if the Due Date is in the Past, but the Status is not yet Done, set a specific percentage (perhaps 90%?)

    =IF(Status@row = "Done", 1, IF([Due Date]@row <= TODAY(), 0.9

    Then the next thing to look for is if the Start Date is in the future (because if it is, the % should be 0):

    =IF(Status@row = "Done", 1, IF([Due Date]@row <= TODAY(), 0.9, IF([Start Date]@row > TODAY(), 0

    However if the status is not Done, the Start Date is in the Past, but the Due Date is in the Future, I would personally use the dates to find the expected % Complete compared to Today.

    (TODAY() - [Start Date]@row) / ([Due Date]@row - [Start Date]@row)

    For a full formula:

    =IF(Status@row = "Done", 1, IF([Due Date]@row <= TODAY(), 0.9, IF([Start Date]@row > TODAY(), 0, (TODAY() - [Start Date]@row) / ([Due Date]@row - [Start Date]@row))))


    Cheers,

    Genevieve

Help Article Resources

Want to practice working with formulas directly in Smartsheet?

Check out the Formula Handbook template!