Formula Help

I have a formula for RYGB balls based on days open. Here are the criteria I'm trying to achieve:

Done is checked = Blank

Red = 365+ days open

Yellow = 300 - 364 days open

Green = 180 - 299 days open

Blue = 0 - 179 days open

The formula I have is =IFERROR(IF(Done@row = 1), "", IF(ISNUMBER([Days Open]@row), IF([Days Open]@row >= 365, "Red", IF(AND([Days Open]@row >= 300, [Days Open]@row < 365), "Yellow", IF(AND([Days Open]@row > 180, [Days Open]@row < 300), "Green")))), "Blue") but it gives me an incorrect arguement set error.

Can somebody please help figure out what I am doing wrong? Thanks!

Find more posts tagged with

Accepted answers

Paul Newcome

Give this one a go. It is going to be shorter than your original formula. The main reason is that if you nest your IF's in a specific order, you don't have to use the AND function to specify that it is between two certain numbers.

If you have "greater than or equal to 365" followed by something else, if it makes it to that "something else" then it is automatically assumed to be less than 365 because that first bit was already found to be false.

=IFERROR(IF(Done@row = 1, "", IF([Days Open]@row >= 365, "Red", IF([Days Open]@row >= 300, "Yellow", IF([Days Open]@row >= 180, "Green", IF(ISNUMBER([Days Open]@row), "Blue"))))), "Blue")

The actual error you are receiving is because of an extra parenthesis. The closing parenthesis here needs to be removed.

IF(Done@row = 1), "",

changes to

IF(Done@row = 1, "",

All comments

Paul Newcome

=IFERROR(IF(Done@row = 1, "", IF([Days Open]@row >= 365, "Red", IF([Days Open]@row >= 300, "Yellow", IF([Days Open]@row >= 180, "Green", IF(ISNUMBER([Days Open]@row), "Blue"))))), "Blue")

The actual error you are receiving is because of an extra parenthesis. The closing parenthesis here needs to be removed.

IF(Done@row = 1), "",

changes to

IF(Done@row = 1, "",

Heather K

Perfect. I figured it was something simple but couldn't seem to figure it out. Thank you very much!

Paul Newcome

Happy to help! 👍️

Sign in to join the conversation!

Quick Links

Component react.discussion.discussions had an error.

ref must be one of: categoryID, siteSectionID, category, category/categoryID, category/name, category/description, category/url, category/allowedDiscussionTypes, locale, siteSection, siteSection/basePath, siteSection/contentLocale, siteSection/sectionGroup, siteSection/sectionID, siteSection/name, siteSection/description, siteSection/apps, siteSection/attributes, layoutViewType, discussionID, commentID, page, latest, sort, sortType, lookupSort, discussion, discussion/name, tags, breadcrumbs, discussionApiParams, serverDraftID, serverDraft.