IF/OR Formula

Holli

Hello - I am trying to make a formula work but having issues. I have a more significant formula that is correct but when I add to it, I mess it up and can't figure out what I'm not doing. I can make each formula work on its own but having trouble merging them.

The following formula works. I need all of it but I also need to add to it.

=IF(OR([Payment Type*]1 = "Overload", [Payment Type*]1 = "Adjunct-Bi-Weekly", [Payment Type*]1 = "PhD-Extra Teaching (5+ yr ONLY)", [Payment Type*]1 = "PhD-Departmental (yrs 1-4, Summer ONLY)", [Payment Type*]1 = "Facilitating-MBA DL", [Payment Type*]1 = "Facilitating-MS Tax DL", [Payment Type*]1 = "Facilitating-Dept", [Payment Type*]1 = "Adjunct-Teaching"), VALUE([Pay per credit/week]1) * ([Credit Hours*]1), IF([Credentials*]1 = "2/9th Base Summer Stipend", ([Annual Salary]1 * (2 / 9)), IF([Credentials*]1 = "1/9th Base Summer Stipend", ([Annual Salary]1 * (1 / 9)), IF([Credentials*]1 = "Course Development", VALUE([Pay per credit/week]1) * ([Credit Hours*]1), IF([Credentials*]1 = "Content Evaluation", VALUE([Pay per credit/week]4) * ([Credit Hours*]1), IF([Payment Type*]1 = "Faculty Summer Teaching", ([Annual Salary]1 * 0.0375) * [Credit Hours*]1, IF([Payment Type*]1 = "GA-Departmental", VALUE([Pay per credit/week]1 * VALUE([No. Pay Periods*]1)))))))))

I need to add the following to the above formula: =IF([Payment Type*]1 = "GA-TA/Tutor", VALUE([Pay per credit/week]1 * VALUE([No. Pay Periods*]1)))

I've tried =IF([Payment Type*]3 = "GA-Departments", [Payment Type*]3 = "GA-TA/Tutor", VALUE([Pay per credit/week]3 * VALUE([No. Pay Periods*]3))) but it throws an error (works on it;s own). I've tried it with an OR but was unsuccessful there also. I believe I'm not closing out the formula correctly, but unsure what to do.

Thanks for the help!

Genevieve P.

Hi @Holli

Looks good! 🙂 It is a matter of closing parentheses, you're right:

=IF(this = "that", VALUE(--) * VALUE(--))

=IF([Payment Type*]1 = "GA-TA/Tutor", VALUE([Pay per credit/week]1) * VALUE([No. Pay Periods*]1))

Can I ask if there's a reason you're using row references, instead of @row?

[Payment Type*]1 for row 1 instead of [Payment Type*]@row for this current row.

If you're looking in the current row, try:

=IF(OR([Payment Type*]@row = "Overload", [Payment Type*]@row = "Adjunct-Bi-Weekly", [Payment Type*]@row = "PhD-Extra Teaching (5+ yr ONLY)", [Payment Type*]@row = "PhD-Departmental (yrs 1-4, Summer ONLY)", [Payment Type*]@row = "Facilitating-MBA DL", [Payment Type*]@row = "Facilitating-MS Tax DL", [Payment Type*]@row = "Facilitating-Dept", [Payment Type*]@row = "Adjunct-Teaching"), VALUE([Pay per credit/week]@row) * [Credit Hours*]@row, IF([Credentials*]@row = "2/9th Base Summer Stipend", ([Annual Salary]@row * (2 / 9)), IF([Credentials*]@row = "1/9th Base Summer Stipend", ([Annual Salary]@row * (1 / 9)), IF([Credentials*]@row = "Course Development", VALUE([Pay per credit/week]@row) * [Credit Hours*]@row, IF([Credentials*]@row = "Content Evaluation", VALUE([Pay per credit/week]@row) * ([Credit Hours*]@row), IF([Payment Type*]@row = "Faculty Summer Teaching", ([Annual Salary]@row * 0.0375) * [Credit Hours*]@row, IF(OR([Payment Type*]@row = "GA-Departmental", [Payment Type*]@row = "GA-TA/Tutor"), VALUE([Pay per credit/week]@row * VALUE([No. Pay Periods*]@row)))))))))