Formula using AND and OR functions

deb_63_hydracor

Hi Paul,

I need to put myself into reverse back to 6/14.

Project Complete is unchecked AND Project Cancelled is unchecked (on 6/15 I told you it should have been OR, but it really should be AND as I initially presented)

• Row creation month is June
• Row creation year is 2022
• Deployment type is either New Deployment OR Package Upgrade

This formula that you provided me with works but I get "0" for an answer which is incorrect (I tried the formula in multiple rows, changing the month, and still always get "0").

=COUNTIFS({Project Complete}, @cell <> 1, {Project Cancelled}, @cell <> 1, {Deployment Type}, OR(@cell = "New Deployment", @cell = "Package Upgrade"), {Sodexo Deployment Queue Row Creation Month}, @cell = "June", {Sodexo Deployment Queue Year}, @cell = "2022")

Thanks again for your help!!

Paul Newcome

How exactly are you outputting the month and year on the source sheet?

deb_63_hydracor

Using the Row Created Date (system generated column), my colleague created the following formulas:

Row Creation Month: =IF(MONTH([Row Creation Date]@row) = 1, "January", IF(MONTH([Row Creation Date]@row) = 2, "February", IF(MONTH([Row Creation Date]@row) = 3, "March", IF(MONTH([Row Creation Date]@row) = 4, "April", IF(MONTH([Row Creation Date]@row) = 5, "May", IF(MONTH([Row Creation Date]@row) = 6, "June", IF(MONTH([Row Creation Date]@row) = 7, "July", IF(MONTH([Row Creation Date]@row) = 8, "August", IF(MONTH([Row Creation Date]@row) = 9, "September", IF(MONTH([Row Creation Date]@row) = 10, "October", IF(MONTH([Row Creation Date]@row) = 11, "November", IF(MONTH([Row Creation Date]@row) = 12, "December"))))))))))))

Row Creation Year: =YEAR([Row Creation Date]@row)

Paul Newcome

Lets try referencing the created date directly...

=COUNTIFS({Project Complete}, @cell <> 1, {Project Cancelled}, @cell <> 1, {Deployment Type}, OR(@cell = "New Deployment", @cell = "Package Upgrade"), {Sodexo Deployment Queue Row Creation Date}, AND(IFERROR(MONTH(@cell), 0) = 6, IFERROR(YEAR(@cell), 0) = 2022))

deb_63_hydracor

Fantastic!!! Thank you SO MUCH for working so hard on this with me!

Paul Newcome

Happy to help. 👍️