Help With Multiple If Formulas

Kirsteen Leckie

Hi,

I am attempting (Badly) to put together a formula to set dates based on a previous date, but also the timeline is based on a yes or no answer, so if the answer is yes there is one timeframe and if no there is another I also don't want errors if the field is blank. So far I have this;

=IFERROR(IF([Client review Required]@row, "Yes", ([Actual Final Client Approval]@row = "", WORKDAY([Expected Final client approval]@row, 5), WORKDAY([Actual Final Client Approval]@row, 5))), IF(OR([Client review Required]@row, "No", ([Actual Compete date]@row = "", WORKDAY([Expected Complete Date]@row, 3), WORKDAY([Actual Compete date]@row, 3)))),"")

I am getting a syntax error and I can't figure out where I am going wrong...all suggestions very welcome!

Kirsteen Leckie

Hi All,

Thank you for your help i managed to get this to work -

=IFERROR(IF([Client review Required]@row = "Yes", WORKDAY([Expected Final client approval]@row, 5), IF([Client review Required]@row = "No", WORKDAY([Expected Complete Date]@row, 3))), "")

parulmishra

Can you kindly share the structure of the sheet. Or just the column names you have

jmyzk_cloudsmart_jp

Hi @Kirsteen Leckie

For complex expressions such as your case, I would first create an IF structure and insert the contents of the IF structure in a step-by-step manner.

(1) IF Structure

=IF([Client review Required]@row = "Yes", "Approval Date", "Complete Date")

(2) "Approval Date", "Complete Date" w/o WORKDAY()

Approval Date :

IF(ISDATE([Actual Final Client Approval]@row), [Actual Final Client Approval]@row, [Expected Final client approval]@row)

Complete Date :

IF(ISDATE([Actual Compete date]@row), [Actual Compete date]@row, [Expected Complete Date]@row)

>>

=IF([Client review Required]@row = "Yes", IF(ISDATE([Actual Final Client Approval]@row), [Actual Final Client Approval]@row, [Expected Final client approval]@row), IF(ISDATE([Actual Compete date]@row), [Actual Compete date]@row, [Expected Complete Date]@row))

(3) Add WORKDAY() function

=IF([Client review Required]@row = "Yes", IF(ISDATE([Actual Final Client Approval]@row), WORKDAY([Actual Final Client Approval]@row, 5), WORKDAY([Expected Final client approval]@row, 5)), IF(ISDATE([Actual Compete date]@row), WORKDAY([Actual Compete date]@row, 3), WORKDAY([Expected Complete Date]@row, 3)))

Please take a look at the following published sample sheet.

https://app.smartsheet.com/b/publish?EQBCT=2b8725049729475eb106df31686ebc22

Kirsteen Leckie

Hi All,

Thank you for your help i managed to get this to work -

=IFERROR(IF([Client review Required]@row = "Yes", WORKDAY([Expected Final client approval]@row, 5), IF([Client review Required]@row = "No", WORKDAY([Expected Complete Date]@row, 3))), "")