Cómo mostrar símbolos de manera automática mediante una fórmula

Marcela

Esta publicación le enseñará cómo crear fórmulas para mostrar un símbolo de una columna de símbolos. Si aprende la sintaxis básica para crear algunas fórmulas diferentes, puede tomar la misma fórmula y cambiar la redacción para que funcione con cualquier tipo de símbolo. 

Comenzaremos con instrucciones IF básicas que funcionan de la siguiente manera:

=IF(*esto* es verdadero; hacer *esto*;de lo contrario; hacer *esto*)

 A continuación, le mostramos una instrucción IF simple ubicada en una columna Indicador que habilitará (1 = habilitado) el indicador si la Fecha de vencimiento a la que se hace referencia está en el pasado:

=IF([Fecha de vencimiento]@row < TODAY(); 1; 0)

Esta misma fórmula se puede utilizar con cualquier símbolo. Usemos los símbolos del clima y mostremos el símbolo Tormentoso si la Fecha de vencimiento está en el pasado y Soleado si no lo está:

=IF([Fecha de vencimiento]@row < TODAY(); "Tormentoso"; "Soleado")

¿Cómo sabe qué texto colocar entre comillas para que coincida con un símbolo? Para comprobar cómo están escritos los símbolos en la columna, seleccione una celda:

NOTA: Estos valores distinguen entre mayúsculas y minúsculas. Si ve una mayúscula, escriba una mayúscula.

 Como otro ejemplo, podemos usar sentencias IF anidadas, que son sentencias IF múltiples combinadas en una sola fórmula. Esto nos brinda más opciones para los resultados de la fórmula.  Así es como funcionan:

 =IF(*esto* es verdadero, hacer *esto*, IF(*esto* es verdadero, hacer *esto*, IF ninguno es verdadero, hacer *esto*))) 

A continuación, le mostramos qué hará la fórmula en estos ejemplos:

Si % Completo es 0%-24%, *primera opción*. Si es 25%-49%, *segunda opción*. Si es 50%-74%, *tercera opción*. Si es 75%-99%, *cuarta opción*. Si es 100%, *quinta opción*.

NOTA: Los porcentajes se ven como decimales en las fórmulas. Esto significa que, si está buscando el 20%, tendrá que escribirlo como 0,2.

 

Barra de progreso:

=IF([% Completo]@row < 0,25; "Vacío"; IF([% Completo]@row < 0,5; "Un cuarto"; IF([% Completo]@row < 0,75; "Mitad"; IF([% Completo]@row < 1; "Tres cuartos"; IF([% Completo]@row = 1; "Todo")))))

Corazones:

=IF([% Completo]@row = 0; "Vacío"; IF([% Completo]@row < 0,25; "Uno"; IF([% Completo]@row < 0,5; "Dos"; IF([% Completo]@row < 0,75; "Tres"; IF([% Completo]@row < 1; "Cuatro"; IF([% Completo]@row = 1; "Cinco"))))))

Si puede aprender a crear fórmulas para un tipo de columna de símbolo, puede crear fórmulas para cualquier tipo de símbolo. El truco es solo aprender qué términos están relacionados con qué símbolo.

 

A continuación, le mostramos algunos artículos de ayuda útiles que puede consultar:

- Función IF

- Función TODAY

- Columnas de símbolos

- Crear y editar fórmulas en Smartsheet