Calculate RAG Overall Project Status

ASorensen

I have projects that are recording Red, Yellow, Green for multiple categories (Budget, Scope, Schedule, Resources), and I would like to be able to calculate the Overall Health by evaluating each of these individual status' and pulling the lowest color as the overall status. What I need to be able to do is calculate the following:

- IF budget, scope, schedule, or resources is Red, then the overall status of the project is Red.

- IF budget, scope, schedule, or resources is Yellow, then the overall status of the project is Yellow.

- IF no Reds or Yellows (all are Green), then the overall status is Green.

I have tried multiple things and had no luck. Any insight is appreciated! Thanks!

L_123

=if(or(budget@row ="Red", Scope@row = "Red" Schedule@row = "Red",Resources@row = "Red"),"Red", if(or(budget@row ="Yellow", Scope@row = "Yellow" Schedule@row = "Yellow",Resources@row = "Yellow"),"Yellow","Green")

L_123

trying to shorten this, assuming the order you put the columns down is the order they are on the sheet:

=if(find("Red", Join(budget@row:resources@row,","))>0,"Red",if(find("Yellow", Join(budget@row:resources@row,","))>0,"Green"))

ASorensen

Thanks for the response! I tried this formula, and it seems to work if there is a red or yellow, but if all of the categories are green it comes back blank. Any ideas how to solve this?

ASorensen

I got it. I made a minor modification and it worked. Thanks!

IF(FIND("Red", JOIN(Budget@row:Resources@row, ",")) > 0, "Red", IF(FIND("Yellow", JOIN(Budget@row:Resources@row, ",")) > 0, "Yellow", "Green"))

L_123

Whoops hahaha. Got a little ahead of myself typing then. Glad you got it.

Paul Newcome

You can also save a few keystrokes by replacing the FIND("Color", JOIN(................)) > 0 with the CONTAINS function.

.

IF(FIND("Red", JOIN(Budget@row:Resources@row, ",")) > 0, "Red", IF(FIND("Yellow", JOIN(Budget@row:Resources@row, ",")) > 0, "Yellow", "Green"))

.

IF(CONTAINS("Red", Budget@row:Resources@row), "Red", IF(CONTAINS("Yellow", Budget@row:Resources@row), "Yellow", "Green"))

.

Just a variation on the same solution.