Creating training Calendar

NP2_

Hi All,

I am currently trying to create a sheet to track who our trainers are currently working with. Currently have 15 trainers, but the team will grow larger in the next few months. Each trainer can train 2 employees at a given time. Employees are trained for 2 weeks.

Ideally, I would like a form that someone can request training through, the training can be approved/denied by the training coordinator, training coordinator looks at the calendar to chose the start and finish date, and then that populates into a calendar. The calendar should send some sort of error when the coordinator tries to book a trainer for more than 2 employees at a time. Calendar should also be visually appealing for upper mgmt.

Any suggestions? I've made a form, and a rough draft of the calendar, but it's not meeting all the needs.

Thanks!

Antonio Figueroa

I would use Resource Management on your sheet using Gantt View. Remember to turn on dependency first.

Genevieve P.

Hi @NP2_

It sounds like you've already set up the first half:

• A form submits a new row
• This new row triggers an alert to the Training Coordinator (or an Update Request if you want them to fill out the details right from their email)
• The Training Coordinator can then update the same row with the Start/End/Trainer

Then what I would do here is have a Flag Symbol column that uses a formula to see if the same Trainer has more than 2 rows on those same dates.

=IF(COUNTIFS(Trainer:Trainer, Trainer@row, [Start Date]:[Start Date], <=[End Date]@row, [End Date]:[End Date], >=[Start Date]@row) > 2, 1, 0)

This way you can easily identify if a row need to be updated, and adjust the most recent entry. You can also set up another Alert to the Training Coordinator if any rows suddenly appear with a flag and Conditional Formatting to highlight the rows.

Then for your higher-level overview:

I would use Conditional Formatting so each Trainer has a specific colour. This is another way to visualize if there are more than 2 of the same colour on one day.

Then you can create a Report and Group it by the Trainer. You can put this in Gantt view to see what's scheduled, and set it to Sort by Date so that everything is in order in the Gantt view, like so:

This way your Training Coordinator can go to the Report and adjust the overlapping dates for the flagged rows, seeing what is available while adjusting the data in the grid view on the left.

I hope that helps!

Cheers,

Genevieve

NP2_

https://community.smartsheet.com/discussion/comment/311443#Comment_311443

Hi Genevieve! I appreciate the help!

I am having a few issues though... I edited the formula to match my column names but can't seem to get it to work. I also created the conditional formatting but it won't apply to the gnatt chart for some reason. Any suggestions?

Thanks again!

Genevieve P.

Hi @NP2_

When you say it's not working, are you getting an error? Can you copy/paste your formula here?

For the Conditional Formatting (see here), the Gantt Chart colour is the Task Bar colour in the formatting option. You have to have the criteria set to apply to the Entire Row for the Task Bar to appear.

Let me know if that helped!

NP2_

https://community.smartsheet.com/discussion/comment/311525#Comment_311525

Here is my formula:

=IF(COUNTIFS(Assigned trainer:Assigned trainer, Assigned trainer@row, [Start]:[Start], <=[Finish]@row, [Finish]:[Finish], >=[Start]@row) > 2, 1, 0)

I used yours as my starting point, and changed the names of the rows in the formula to match my sheet. When I use it, it says #unparseable

Thank you!

Genevieve P.

Hi @NP2_

If a column name has a space or a number in it, it needs to be referenced [in these] so the formula knows when the name starts and stops. However if there are no spaces or numbers you can list the names outright without [these].

Try this:

=IF(COUNTIFS([Assigned trainer]:[Assigned trainer], [Assigned trainer]@row, Start:Start, <= Finish@row, Finish:Finish, >=Start@row) > 2, 1, 0)

See:Create a Cell or Column Reference in a Formula

Cheers!

Genevieve

NP2_

https://community.smartsheet.com/discussion/comment/311639#Comment_311639

Genevieve,

That worked! Thank you so much!

Genevieve P.

No problem at all! Thanks for letting me know it worked 🙂

NP2_

https://community.smartsheet.com/discussion/comment/311643#Comment_311643

Another question for you.... Is there a way that I can make the row be flagged if a trainer has not been assigned, or the trainer assigned is overbooked (which has been changed to be more than one trainee at a time)?

Here is my current formula:

=IF(COUNTIFS([Assigned trainer]:[Assigned trainer], [Assigned trainer]@row, [Start Date]:[Start Date], <=[Tentative Finish Date]@row, [Tentative Finish Date]:[Tentative Finish Date], >=[Start Date]@row) > 0, 1)

Genevieve P.

Hi @NP2_

It sounds like you just want to add a rule that if the cell is blank, flag the flag as well?

Try this:

=IF(OR([Assigned trainer]@row = "", COUNTIFS([Assigned trainer]:[Assigned trainer], [Assigned trainer]@row, [Start Date]:[Start Date], <=[Tentative Finish Date]@row, [Tentative Finish Date]:[Tentative Finish Date], >=[Start Date]@row) > 0), 1)

Cheers,

Genevieve

NP2_

https://community.smartsheet.com/discussion/comment/316048#Comment_316048

Thank you so much! That worked perfectly!