Summarizing result of a formula

Ldonoghue

Hello,

I have a report that groups and summarizes points earned by individuals - well, it's supposed to do so, but the summary of points doesn't work. This appears to be because the points are calculated by a formula - if I just enter numbers, I can get a sum, but if the number are the result of a formula, the sum = 0. Does anyone know of a workaround for this? I tried adding a column to the source sheet to copy the result - but that is also a formula, so same result. Appreciate any suggestions.

Paul Newcome

It is fine using a formula as long as the formula is outputting numbers. What formula are you using?

Paul Newcome

It is fine using a formula as long as the formula is outputting numbers. What formula are you using?

Ldonoghue

Aha! I was going to respond that it was outputting numbers but when I looked at my formula I realized it had the numbers inside quotation marks. Removed those and it works - thank you!!

Paul Newcome

Happy to help. 👍️

Ldonoghue

You know that no good deed goes unpunished, right? :-) I have another one. The following formula works for every variable except "Three Quarter" - which references the progress bar display. Thoughts? I've tested it as the only IF/AND and it does not seem to recognize Three Quarter. Same issue with other progress symbols.

=IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = ""), "Late", IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = "Empty"), "Late", IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = "Quarter"), "In Progress", IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = "Half"), "In Progress",IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = "Three Quarter"), IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = "Full"), "Complete", ""))))))

Paul Newcome

You don't have an output for the "Three Quarter" piece.

You need:

IF(AND("three quarter" argument), "output", IF(AND(.....)

You have:

IF(AND("three quarter" argument), IF(AND(.....)

Paul Newcome

Here are some tips that will save you some typing...

If you are adding the same piece to every argument with an AND function, you can start things off with an IF statement to only say it once and then follow through with the output of the first IF statement being the nested IF.

=IF(TODAY() > [Start Date]@row, IF([Completion Progress]@row = "", "Late", IF([Completion Progress]@row = "Empty", "Late", IF([Completion Progress]@row = "Quarter", "In Progress", IF([Completion Progress]@row = "Half", "In Progress", IF([Completion Progress]@row = "Three Quarter", "In Progress", IF([Completion Progress]@row = "Full", "Complete", "")))))))

You can also combine arguments using an OR statement if they all have the same output.

=IF(TODAY()> [Start Date]@row, IF(OR([Completion Progress]@row = "", [Completion Progress]@row = "Empty"), "Late", IF(OR([Completion Progress]@row = "Quarter", [Completion Progress]@row = "Half", [Completion Progress]@row = "Three Quarter"), "In Progress", IF([Completion Progress]@row = "Full", "Complete", ""))))

If you leave the "value if false" portion empty, it will output a blank for anything that doesn't fit the previously specified criteria.

=IF(TODAY()> [Start Date]@row, IF(OR([Completion Progress]@row = "", [Completion Progress]@row = "Empty"), "Late", IF(OR([Completion Progress]@row = "Quarter", [Completion Progress]@row = "Half", [Completion Progress]@row = "Three Quarter"), "In Progress", IF([Completion Progress]@row = "Full", "Complete"))))

You don't HAVE to (in this case) have the nested IFs in order since you are specifying every step of the way, so you can rearrange them to do the easiest pieces and then leave the one that has the most options in the OR function as the "value if false".

=IF(TODAY()> [Start Date]@row, IF(OR([Completion Progress]@row = "", [Completion Progress]@row = "Empty"), "Late", IF([Completion Progress]@row = "Full", "Complete", "In Progress")))

Which as you can see is much more consolidated than your original formula:

=IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = ""), "Late", IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = "Empty"), "Late", IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = "Quarter"), "In Progress", IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = "Half"), "In Progress", IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = "Three Quarter"), "In Progress", IF(AND(TODAY() > [Start Date]@row, [Completion Progress]@row = "Full"), "Complete", ""))))))

vs

=IF(TODAY()> [Start Date]@row, IF(OR([Completion Progress]@row = "", [Completion Progress]@row = "Empty"), "Late", IF([Completion Progress]@row = "Full", "Complete", "In Progress")))

Ldonoghue

Thanks for the shortcut - that worked! I promise to leave you be now!

Paul Newcome

Happy to help. 👍️