10 rows Created: Only want one approval notification & response to control all rows

I use an order form and some fancy footwork (learned from these forums) to copy 10 rows of duplicate data for each order to a sheet, all duplicate except for the Item ordered itself.

Below is an example of ONE form submission containing 10 items ordered:

{6C8BD16D-903A-404D-B3D6-3C9C4213A09E}.png

However, now I need to:

Send one approval email request to the Supervisor.
1. When the Supervisor gets the email it needs to contain all the items ordered. Once
After it's approved, I need all rows to be marked as approved/denied/etc.

Does anyone have any ideas on how I should go about doing this?

More info:

The order number will always be the same for the same order, in fact, all the data before "Exchange Item Ordered" will be identical.
I don't want to do the approval process on the previous sheet.
Sometimes, the end-user will need to mark the row as approved manually.

Find more posts tagged with

Approval Request

row

nowwhatdoido?

Accepted answers

NeilKY

For anyone interested, what i ended up doing was a little different:

New rows come into this sheet, multiple rows per order.
Sheet calculates which row has lowest "Auto-Number" for any given order. ("Entire Order Approval Status" Col)
System requests approval for "Entire Order Approval Status" (or lowest auto-number for that order).
Other rows for that order are equal to that row's value. So when the one row gets approved, they all get marked as approved.
"Line Item Approval Status" becomes the final authoritative source of whether a row is approved or not.
Bonus: If they want to approve / deny by line item they can, which overwrites what the "Entire Order Approval Status" value is.

Here's the formula in "Line item approval status":

=IF([Approval Override (Line Item)]@row <> "", [Approval Override (Line Item)]@row, IFERROR(INDEX([Entire Order Approval Status (Via Email)]:[Entire Order Approval Status (Via Email)], MATCH([Order Number]@row, [Order # for Min auto #]:[Order # for Min auto #], 0)), ""))

{31816E3C-30B4-45F6-B9FC-53A3ABDD7883}.png

Other calculation columns:

[Items Ordered] column, combines ordered item from every row with that order #. Formula:

=IF([Order # for Min auto #]@row > 0, JOIN(COLLECT([Item & Quantity]:[Item & Quantity], [Order Number]:[Order Number], [Order Number]@row), CHAR(10)), "")

2. [Primary approval row for order], determines lowest auto-nunber for row:

=IF([Auto Number]@row = MIN(COLLECT([Auto Number]:[Auto Number], [Order Number]:[Order Number], [Order Number]@row)), 1, 0)

3. [Order # for Min auto #], determines order # for minimum auto number :)

=IF([Auto Number]@row = MIN(COLLECT([Auto Number]:[Auto Number], [Order Number]:[Order Number], [Order Number]@row)), [Order Number]@row, 0)

4. [Item & Quantity], adds the quantity ordered to the item for each row

=[Exchange Quantity Ordered]@row + "x-" + [Exchange Item Ordered]@row

{877266CA-C129-47F4-B639-912299B7B89C}.png

All comments

kowal

hello again @NeilKY,

you can send dozens of request of update as one email to a person.

He will get a link to 1 form and at the bottom ther ewill be this arrow to go to the next form to update another row etc.

there will be one submit button that will be updating everyting at once.

All you have to do is to avoid sending dynamic data in the email like {{product number}} if it recognises that it's differnt text it will send it as separate meail.

Paul Newcome

You would need to manage the approval from the first sheet that has everything on the same row. You can either set your system up to copy the individual rows over after approval has been completed, or you can use formulas with cross sheet references such as INDEX/MATCH or INDEX/COLLECT to bring the approval decision over to the individual row sheet. Either way, the approval would been to be sent from the first sheet if you want them to be able to "bulk approve".

NeilKY

https://community.smartsheet.com/discussion/comment/478083#Comment_478083

Thank you both, I learned some things today!

@kowal, Each row has all identical information except for the item ordered and quantity. Are you referring to "Approvals" or "Update Requests"? I can replicate one email for multiple rows with update requests, but I don't know how to prevent multiple emails in approval requests?

kowal

hi @NeilKY

yeah for approval request it would not work as each row is 1 email for approval.

only the request of update from many rows you can squeeze to one email.

so the tip given by @Paul Newcome is the most accurate.

NeilKY

For anyone interested, what i ended up doing was a little different:

New rows come into this sheet, multiple rows per order.
Sheet calculates which row has lowest "Auto-Number" for any given order. ("Entire Order Approval Status" Col)
System requests approval for "Entire Order Approval Status" (or lowest auto-number for that order).
Other rows for that order are equal to that row's value. So when the one row gets approved, they all get marked as approved.
"Line Item Approval Status" becomes the final authoritative source of whether a row is approved or not.
Bonus: If they want to approve / deny by line item they can, which overwrites what the "Entire Order Approval Status" value is.

Here's the formula in "Line item approval status":

Other calculation columns:

[Items Ordered] column, combines ordered item from every row with that order #. Formula:

=IF([Order # for Min auto #]@row > 0, JOIN(COLLECT([Item & Quantity]:[Item & Quantity], [Order Number]:[Order Number], [Order Number]@row), CHAR(10)), "")

2. [Primary approval row for order], determines lowest auto-nunber for row:

=IF([Auto Number]@row = MIN(COLLECT([Auto Number]:[Auto Number], [Order Number]:[Order Number], [Order Number]@row)), 1, 0)

3. [Order # for Min auto #], determines order # for minimum auto number :)

=IF([Auto Number]@row = MIN(COLLECT([Auto Number]:[Auto Number], [Order Number]:[Order Number], [Order Number]@row)), [Order Number]@row, 0)

4. [Item & Quantity], adds the quantity ordered to the item for each row

=[Exchange Quantity Ordered]@row + "x-" + [Exchange Item Ordered]@row

Sign in to join the conversation!

Quick Links

Component react.discussion.discussions had an error.

ref must be one of: categoryID, siteSectionID, category, category/categoryID, category/name, category/description, category/url, category/allowedDiscussionTypes, locale, siteSection, siteSection/basePath, siteSection/contentLocale, siteSection/sectionGroup, siteSection/sectionID, siteSection/name, siteSection/description, siteSection/apps, siteSection/attributes, layoutViewType, discussionID, commentID, page, sort, discussion, discussion/name, tags, breadcrumbs, discussionApiParams, serverDraftID, serverDraft.